Slitherine

Code: Select all

// -1 means don't even consider firing
FUNCTION REACT_Unit_Shoot(me, unit)
{
	return -1; // No reaction shooting.
}

Code: Select all

// we return a score to determine who should fire
// -1 means don't even consider firing
// Units less likely to reaction fire if target at long range or out of full arc of fire. Lower quality troops more likely to shoot at the wrong moment.
FUNCTION REACT_Unit_Shoot(me, unit)
{
	int distance;
	int range;
	int damage ;
	int effectiveness ;
	int x;
	int y;
	int side;
	int volley;
	int priority_target;
	int reaction_chance;
	int quality;
	int percent;

	// Artillery and Ships don't reaction fire as such. (But they do get to use up their "reaction" shot in Housekeeping Shooting.)
	if ((IsArtillery(me) == 1) || (IsUnitSquadType(me, "Ship") == 1))
		{
			return -1;
		}

	effectiveness = -1 ;

	x = GetUnitX(me);
	y = GetUnitY(me);
	side = GetUnitSide(unit);

	// LOS is checked in the code
	// only react fire if hold fire is false or if it is adjacent
	if ((GetAttrib(me, "HoldFire") == 0) || (GetTileLOS(x,y,side) == 1))
		{
			if ((GetAttrib(me, "MoraleState") < 3)) // If not routed/destroyed
				{
					distance = GetDistanceBetween(me, unit);
					range = MaximumRange(me);
					volley = ArcOfFire(me, unit);

					// if in range and arc of fire
					if ((distance <= range) && (volley > 0))
						{
							effectiveness = CalculateShootingDamage(me, unit, volley, 1, 0, 1); // effectiveness takes into account range and arc of fire

							if (effectiveness > 0)
								{
									// Hold fire if there is another targetable priority target
									priority_target = PriorityChargeTarget(me, unit);
									if (unit != priority_target)
										{
											if (CallUnitFunctionDirect(me, "CHECK_UNIT_SHOOT", me, priority_target, GetUnitX(priority_target), GetUnitY(priority_target), 1, 1) >= 0)
												{
													effectiveness = -1;
												}
										}
									else
										{
											percent = 25; // May need tweaking
											quality = Max(percent, GetQuality(me)); // To prevent a /0 error, and reaction chance going above 100%
											reaction_chance = 100;
											if (volley != 3)
												{
													reaction_chance *= percent;
													reaction_chance /= quality;
												}
											if (IsLongRange(me, unit) == 1)
												{
													reaction_chance *= percent;
													reaction_chance /= quality;
												}
//                      Log ("reactor, enemy unit, reaction_chance", me, unit, reaction_chance);
											if (Rand(1,100) >= reaction_chance)
												{
													effectiveness = -1;
												}
										}
								}
							else
								{
									effectiveness = -1;
								}

						}
				}
		}

	return effectiveness;
}